<Минимальное значение> ::= <Константное выражение типа Real>
<Максимальное значение> ::= <Константное выражение типа Real>
<Установление значений статических переменных> ::= <Установление параметров Подсети> [;<Установление значений статических переменных>]
<Описание методов> ::= <Описание функционирования вперед> <Описание функционирования назад>
<Описание функционирования вперед> ::= Forw [<Описание переменных>] <Тело метода>
<Тело метода> ::= Begin <Составной оператор> End
<Описание функционирования назад> ::= Back [<Описание переменных>] <Тело метода>
<Конец описания элемента> ::= End <Имя элемента>
<Описание блока> ::= <Заголовок описания блока> <Описание состава> <Описание сигналов и параметров> [<Описание статических переменных>] [<Установление значений статических переменных>] <Описание связей> [<Определение типов параметров>] <Конец описания блока>
<Заголовок описания блока> ::= {<Описание каскада> ½ <Описание слоя> ½ <Описание цикла с фиксированным числом шагов> ½ <Описание цикла по условию>}
<Описание каскада> ::= Cascad <Имя блока> [(<Список формальных аргументов блока>)]
<Имя блока> ::= <Идентификатор>
<Список формальных аргументов блока> ::= {<Список формальных аргументов> ½ <Аргумент – подсеть>} [;<Список формальных аргументов блока>]
<Аргумент – подсеть>::= <Список имен аргументов – подсетей> : Block
<Список имен аргументов – подсетей> ::= <Имя аргумента – подсети> [,<Список имен аргументов – подсетей>]
<Имя аргумента – подсети> ::= <Идентификатор>
<Описание слоя> ::= Layer <Имя блока> [(<Список формальных аргументов блока>)]
<Описание цикла с фиксированным числом шагов> ::= Loop <Имя блока> [(<Список формальных аргументов блока>)] <Число повторов цикла>
<Число повторов цикла> ::= <Константное выражение типа Long>
<Описание цикла по условию> ::= Until <Имя блока> [(<Список формальных аргументов блока>)] : <Выражение типа Logic>
<Описание состава> ::= Contents <Список имен подсетей>
<Список имен подсетей> ::= <Имя подсети> [,<Список имен подсетей>]
<Имя подсети> ::= <Псевдоним>: {<Имя ранее описанной подсети> [(<Список фактических аргументов блока>)] [[<Число экземпляров>]] ½ <Имя аргумента – подсети> [[<Число экземпляров >]]}
<Псевдоним> ::= <Идентификатор>
<Число экземпляров > ::= <Константное выражение типа Long>
<Имя ранее описанной подсети> ::= <Идентификатор>
<Список фактических аргументов блока> ::= <Фактический аргумент блока> [,<Список фактических аргументов блока>]
<Фактический аргумент блока> ::= {<Фактический аргумент> ½ <Имя аргумента – подсети>}
<Описание связей> ::= {<Описание распределения Входных сигналов, Блока, Подсети, InSignals > ½ <Описание распределения Выходных сигналов, Блока, Подсети, OutSignals > ½ <Описание распределения Параметров, Блока, Подсети, Parameters >}
<Конец описания блока>::= End <Имя блока>
<Конец описания библиотеки> ::= End NetLib
<Описание сети> ::= <Заголовок описания сети> <Описание подсетей> <Описание главной сети> <Массивы параметров и масок сети> <Конец описания сети>
<Заголовок описания сети> ::= NetWork <Имя сети> [Used <Список имен библиотек>]
<Имя сети> ::= <Идентификатор>
<Описание главной сети> ::= MainNet <Имя ранее описанной подсети> [(<Список фактических аргументов блока>)]
<Массивы параметров и масок сети> ::= <Массив параметров> <Массив маски обучаемости параметров>
<Массив параметров> ::= Parameters <Значения параметров>;
<Значения параметров> ::= <Действительное число> [, <Значения параметров>]
<Массив маски обучаемости параметров> ::= ParamMask <Значения маски>;
<Значения маски> ::= <Константа типа Logic> [,<Значения маски>]
<Конец описания сети> ::= End NetWork
В этом разделе приводится детальное описание языка описания сетей, дополняющее БНФ, приведенную в предыдущем разделе и описание общих конструкций, приведенное в разделе «Общий стандарт».
Вспомогательные переменные могут потребоваться при описании прямого и обратного функционирования элементов. Переменная действует только в пределах той процедуры, в которой она описана. Кроме явно описанных переменных, в методе Forw доступны также сигналы прямого функционирования и параметры элемента, а в методе Back – входные и выходные сигналы прямого функционирования, выходные сигналы обратного функционирования, параметры элемента и градиент по параметрам элемента. Во всех методах доступны аргументы элемента.
Статические переменные, описываемые после ключевого слова Static, уникальны для каждого экземпляра элемента или блока, и доступны только в пределах элемента или блока. Эти переменные могут потребоваться для вычисления условий в цикле типа Until. Возможно использование таких переменных в элементах, например, для хранения предыдущего состояния элемента. Кроме того, в статической переменной можно хранить значения не обучаемых параметров.
Методы Forw и Back для блоков не описываются в языке описания сетей. Это связано с тем, что при выполнении метода Forw блоком происходит вызов метода Forw составляющих блок подсетей (для элементов – метода Forw) в порядке их описания в разделе описания состава блока. При выполнении метода Back происходит вызов методов Back составляющих блок подсетей в порядке обратном порядку их описания в разделе описания состава блока.
Описание элемента состоит из следующих основных разделов: заголовка элемента, описания сигналов и параметров, описания статических переменных и описания методов. Заголовок элемента имеет следующий синтаксис:
Element Имя_Элемента (Аргументы элемента)
Аргументы элемента являются необязательной частью заголовка. В следующем разделе приведены описания нескольких элементов. Отметим, что сигмоидный элемент описан двумя способами: с принципиально не обучаемой (S_NotTrain) и с обучаемой (S_Train) характеристикой.
Раздел описания сигналов и параметров следует сразу после заголовка элемента и состоит из указания числа входных и выходных сигналов и числа параметров элемента. Если у элемента отсутствуют параметры, то указание числа параметров можно опустить. В следующем разделе приведены элементы как имеющие параметры (S_Train, Adaptiv_Sum, Square_Sum), так и элементы без параметров (Sum, S_NotTrain, Branch). Концом раздела описания сигналов и параметров служит одно из ключевых слов ParamType, ParamDef, Forw или Back.
Описание типов параметров является необязательной частью описания элемента и начинается с ключевого слова ParamType. Если раздел описания типов параметров отсутствует, то все параметры этого элемента считаются параметрами типа DefaultType. Если в сети должны присутствовать параметры разных типов (например с разными ограничениями на минимальное и максимальное значение) необходимо описать типы параметров. Концом этого раздела служит одно из ключевых слов ParamDef, Forw или Back.
Раздел определения типов параметров является необязательным разделом в описании элемента и начинается с ключевого слова ParamDef. В каждой строке этого раздела можно задать минимальную и масимальную границы изменения одного типа параметров. Если в описании сети встречаются параметры неопределенного типа то этот тип считается совпадающим с типом DefaultType. Описание типа не обязано предшествовать описанию параметров этого типа. Так например, определение типа параметров может находиться в описании главной сети. Концом этого раздела служит одно из ключевых слов Forw или Back.
Раздел описания методов состоит из описания двух методов: Forw и Back. Описание метода состоит из заголовка, раздела описания переменных и тела метода. Заголовок имеет вид ключевого слова Forw или Back для соответствующего метода. Раздел описания переменных состоит из ключевого слова Var, за которым следуют описания однотипных переменных, каждое из которых заканчивается символом «;». Необходимо понимать, что описание заголовков методов это не описание заголовка (прототипа) функции, выполняющей тело метода. Ниже приведен синтаксис заголовков методов Forw и Back на момент вызова:
Pascal:
Procedure Forw( InSignals, OutSignals, Parameters : PRealArray);
Procedure Back(InSignals, OutSignals, Parameters, Back.InSignals,
Back.OutSignals, Back.Parameters : PRealArray);
C
void Forw(PRealArray InSignals, PRealArray OutSignals, PRealArray Parameters)
void Back(PRealArray InSignals, PRealArray OutSignals, PRealArray Parameters,
PRealArray Back.InSignals, PRealArray Back.OutSignals, PRealArray
Страницы: 1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15, 16, 17, 18, 19, 20, 21, 22, 23, 24, 25, 26, 27, 28, 29, 30, 31, 32, 33, 34, 35, 36, 37, 38, 39, 40, 41, 42, 43, 44, 45, 46, 47, 48, 49, 50, 51, 52, 53, 54, 55, 56, 57, 58, 59, 60, 61, 62, 63, 64, 65, 66, 67, 68, 69, 70, 71, 72, 73, 74, 75, 76
